# You can place the script of your game in this file.

# Declare images below this line, using the image statement.
# eg. image eileen happy = "eileen_happy.png"

image bg morrowind = "morrowind.jpg"
image bg parthenon = "wikipedia_parthenon.jpg"

image hazel normal = "djinni_hazel.jpg"


# The following line auto-switches between pictures that will be referenced by the image name "skunk". See https://www.renpy.org/doc/html/displayables.html .
image skunk = ConditionSwitch("skunk_form == \"feral\"", "djinni_feral_skunk.jpg",
"skunk_form == \"taur\"", "djinni_skunktaur.jpg",
"True", "djinni_skunk.jpg")

# Declare characters used by this game.
define h = Character('Hazel', color="#c8ffc8")
define s = Character('Skunk', color="#3030F0")

# The game starts here.
label start:
    $skunk_form = "anthro"
    scene bg morrowind
    show hazel normal at topright
    with dissolve

    h "Hi there!"
    
    show skunk at topleft
    with dissolve

    h "You're an anthro skunk right now. I'm going to turn you into one of two things. Do you want to be a feral skunk, or a skunktaur?"
    
    s "What the heck?"
    
    h "No, really. It's the best set of icons the writer had available for three distinct forms of one character. Pick one."
    
    menu:
        "Feral, I guess?":
            jump feral
        "Taur!":
            jump taur

            
label feral:
    $skunk_form = "feral"
    s "Huh."
    s "That was odd. I feel small!"
    jump shared_ending
    
    
label taur:
    $skunk_form = "taur"
    s "Wow! I've got... too many legs."
    jump shared_ending


label shared_ending:
    h "And you have no pants!"
    s "Eek!"
    h "Don't worry about it. Anyway, this part of the scene is shared by both story branches. Your current image is displayed based on what I turned you into."
    
    h "Now I'll comment on something based on your current form. The value of the variable is: \"[skunk_form]\". That's the raw value. Next we'll jump to one of two branches based on what you are."
    
    if skunk_form == "feral":
        s "I'm in a feral animal form."
        jump last_part
    else:
        s "I'm in a taur form."
        jump last_part
    
label last_part:
    scene bg parthenon
    show skunk at truecenter
    with dissolve
    s "And that's it for this demo. As you can see we're in a new scene and I've kept whatever image I was using after the change in the previous scene."
    return